@echo off
::
:: Usage : 
::       make.bat [maya_version]
:: 
:: Example :
::       Build plugin for maya version 2020
::       > make.bat 2020
::
:: -------------------------------------
setlocal EnableDelayedExpansion

set maya_ver=%1
set maya_install_base=C:\aw

if "%1" == "" (
	echo "Maya version is not specify. exit."
	goto end
)

if "%2" NEQ "" (
	set maya_install_base=%2
)

cd %~dp0
set current=%cd%
set is_build_tool=0
if not defined VisualStudioVersion (

	echo "VisualStudioVersion is not set, setup %maya_ver% compiler..."

	if %maya_ver% LSS 2020 (
		set compiler_ver=9.0
		if %maya_ver% LEQ 2014 set compiler_ver=10.0
		if %maya_ver% GEQ 2015 set compiler_ver=11.0
		if %maya_ver% GEQ 2018 set compiler_ver=14.0
		set compiler_bat="%ProgramFiles(x86)%\Microsoft Visual Studio !compiler_ver!\VC\vcvarsall.bat" x86_amd64
	)

	if %maya_ver% EQU 2020 (
		if exist "%ProgramFiles(x86)%\Microsoft Visual Studio 2017\WDExpress\VC\Auxiliary\Build\vcvarsall.bat" (
			set compiler_bat="%ProgramFiles(x86)%\Microsoft Visual Studio 2017\WDExpress\VC\Auxiliary\Build\vcvarsall.bat" x86_amd64
			set compiler_ver=15.0
		)
		if exist "%ProgramFiles(x86)%\Microsoft Visual Studio\2017\BuildTools\Common7\Tools\VsDevCmd.bat" (
			set compiler_bat="%ProgramFiles(x86)%\Microsoft Visual Studio\2017\BuildTools\Common7\Tools\VsDevCmd.bat"
			set compiler_ver=15.0
		)
	)
	if %maya_ver% GEQ 2022 (
		if exist "%ProgramFiles(x86)%\Microsoft Visual Studio\2019\Community\VC\Auxiliary\Build\vcvarsall.bat" (
			set compiler_bat="%ProgramFiles(x86)%\Microsoft Visual Studio\2019\Community\VC\Auxiliary\Build\vcvarsall.bat" x86_amd64
			set compiler_ver=16.0
		)
	)
	set VisualStudioVersion=!compiler_ver!

	if not exist !compiler_bat! (
		echo "Can\'t find !compiler_bat!"
		goto end
	)
	echo !compiler_bat!
	call !compiler_bat!
)

if not defined VisualStudioVersion (
	echo "VisualStudioVersion is not set correct."
	goto end
)

IF %VisualStudioVersion% == 11.0 set vc_config=Visual Studio 11 2012 Win64
IF %VisualStudioVersion% == 12.0 set vc_config=Visual Studio 12 2013 Win64
IF %VisualStudioVersion% == 14.0 set vc_config=Visual Studio 14 2015 Win64
IF %VisualStudioVersion% == 15.0 set vc_config=Visual Studio 15 2017 Win64
IF %VisualStudioVersion% == 16.0 set vc_config=Visual Studio 16 2019

set install_dir=%current%\install

if exist build ^
rmdir build /S/Q

if not exist build ^
mkdir build

cd build

cmake -G "%vc_config%"^
 -DCMAKE_INSTALL_PREFIX=%install_dir%^
 -DMAYA_INSTALL_BASE_PATH="%maya_install_base%"^
 -DMAYA_VERSION=%maya_ver%^
 ..

:build 
cmake --build . --target install --config Release -- /maxcpucount:8

:end
cd %current%

endlocal